Remove assets from repository and download them using xmake

assets/shaders/tone_mapping.nzsl

@@ -0,0 +1,58 @@
+[nzsl_version("1.0")]
+module;
+
+import Engine.ViewerData;
+
+external
+{
+	[set(0), binding(0)] viewerData: uniform[ViewerData],
+	[set(0), binding(1)] inputTexture: sampler2D[f32]
+}
+
+struct FragIn
+{
+	[location(0)] uv: vec2[f32],
+}
+
+struct FragOut
+{
+	[location(0)] color: vec4[f32]
+}
+
+struct VertIn
+{
+	[location(0)] pos: vec2[f32],
+	[location(1)] uv: vec2[f32],
+}
+
+struct VertOut
+{
+	[location(0)] uv: vec2[f32],
+	[builtin(position)] position: vec4[f32]
+}
+
+[entry(frag)]
+fn main(input: FragIn) -> FragOut
+{
+	let exposure = 0.8;
+
+	let hdrColor = inputTexture.Sample(input.uv).rgb;
+
+	// reinhard tone mapping
+	let mapped = vec3[f32](1.0, 1.0, 1.0) - exp(-hdrColor * exposure);
+
+	let output: FragOut;
+	output.color = vec4[f32](mapped, 1.0);
+
+	return output;
+}
+
+[entry(vert)]
+fn main(input: VertIn) -> VertOut
+{
+	let output: VertOut;
+	output.position = vec4[f32](input.pos, 0.0, 1.0);
+	output.uv = input.uv;
+
+	return output;
+}